2016年7月29日，微軟關閉Win7/Win8.1免費升級Win10的通道，本文發(fā)稿時間為關閉前一天，此時如果還有用戶想升級Windows10但沒有升級的，可以嘗試使用本文方法進行全新安裝。全新安裝的好處就是不會產(chǎn)生新舊系統(tǒng)各種銜接不暢的問題，雖說現(xiàn)在升級安裝Win10后的體驗不像一年前那么差了，但這種本質(zhì)性的差異是Windows系統(tǒng)升級安裝的通病，很難避免。
當然，免費激活這事可能還是直接升級的更保險，因為一般來說升級之前的系統(tǒng)都是激活好了的，雖然大家激活系統(tǒng)方式可謂“條條大路通羅馬”吧，但微軟一般也沒計較什么，都給予了激活狀態(tài)的Win10。不過使用全新安裝再輸入產(chǎn)品密鑰的方式可能更適合正版用戶，或者自己手中有合法密鑰（至少密鑰沒被封禁）的用戶。如果你能夠確認手中的密鑰沒有問題，不妨嘗試一下IT之家的方法。操作上很簡單，只需要把如下代碼使用記事本等保存為.vbs格式（文件名自擬），雙擊運行即可，適用于Win7/Win8.1/Win10系統(tǒng)。
▲圖片說明：這幅圖的意思并非企業(yè)版支持免費升級，而是說本文方法同樣適用于企業(yè)版密鑰查詢和備份
代碼如下：
Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "系統(tǒng)名稱：" & objshell.RegRead(Path & "ProductName")
ProductID = "產(chǎn)品ID：" & objshell.RegRead(Path & "ProductID")
ProductKey = "已安裝密鑰：" & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "要將密鑰保存到文件嗎？", vbYesNo + vbQuestion, "軟媒魔方備份Windows密鑰信息") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin10, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 10
isWin10 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin10 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0
If (isWin10 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\Windows密鑰備份.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function
----------- IT之家分割線 ------------
▲圖片說明：代碼粘貼到記事本后，另存為.vbs格式
▲圖片說明：運行效果，備份密鑰會以文本文件（.txt）的形式保存到桌面
▲圖片說明：保存密鑰文件的內(nèi)容
當然，自己手動新建文件，復制和粘貼代碼再保存怪麻煩的，所以各位直接在下方下載現(xiàn)成的文件就省心了，下來之后直接運行。
Windows 產(chǎn)品密鑰查詢備份文件：網(wǎng)盤下載（2KB）
另外，軟媒魔方（點擊下載）也有Win7/Win8.1以及Office產(chǎn)品密鑰備份激活功能，無需記住密鑰，而且可以直接在魔方中還原激活，有需要的用戶可以下載使用。
Win10一周年更新版如何激活？點此查看激活秘笈。
廣告聲明：文內(nèi)含有的對外跳轉鏈接（包括不限于超鏈接、二維碼、口令等形式），用于傳遞更多信息，節(jié)省甄選時間，結果僅供參考，IT之家所有文章均包含本聲明。